1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
|
/*
* Mach Operating System
* Copyright (c) 1992,1991,1990,1989 Carnegie Mellon University
* All Rights Reserved.
*
* Permission to use, copy, modify and distribute this software and its
* documentation is hereby granted, provided that both the copyright
* notice and this permission notice appear in all copies of the
* software, derivative works or modified versions, and any portions
* thereof, and that both notices appear in supporting documentation.
*
* CARNEGIE MELLON ALLOWS FREE USE OF THIS SOFTWARE IN ITS "AS IS"
* CONDITION. CARNEGIE MELLON DISCLAIMS ANY LIABILITY OF ANY KIND FOR
* ANY DAMAGES WHATSOEVER RESULTING FROM THE USE OF THIS SOFTWARE.
*
* Carnegie Mellon requests users of this software to return to
*
* Software Distribution Coordinator or Software.Distribution@CS.CMU.EDU
* School of Computer Science
* Carnegie Mellon University
* Pittsburgh PA 15213-3890
*
* any improvements or extensions that they make and grant Carnegie Mellon
* the rights to redistribute these changes.
*/
#include <asm_style.h>
#if 0 /* is this useful? */
/* l2rbcopy(from, to, bcount) */
ENTRY(l2rbcopy)
pushl %ebp
movl %esp,%ebp
pushl %edi
pushl %esi
movl B_ARG2,%edx
movl B_ARG1,%edi
movl B_ARG0,%esi
/* move longs */
0: cld
movl %edx,%ecx
sarl $2,%ecx
js 1f
rep
movsl
/* move bytes */
movl %edx,%ecx
andl $3,%ecx
rep
movsb
1:
popl %esi
popl %edi
leave
ret
#endif
/*
* bcopy - like l2rbcopy, but recognizes overlapping ranges and handles
* them correctly.
* bcopy(from, to, bytes)
* char *from, *to;
* int bytes;
*/
ENTRY(bcopy)
pushl %ebp
movl %esp,%ebp
pushl %edi
pushl %esi
movl B_ARG0,%esi
movl B_ARG1,%edi
bcopy_common:
movl B_ARG2,%edx
leal (%esi,%edx), %eax /* from + bytes */
cmpl %eax, %edi /* <= to */
jae 0f
leal (%edi,%edx), %eax /* to + bytes */
cmpl %eax, %esi /* <= from */
jae 0f
cmpl %esi, %edi /* from > to */
jb 0f
je 1f
addl %edx, %esi; decl %esi
addl %edx, %edi; decl %edi
std
movl %edx,%ecx
/* move bytes backwards */
rep
movsb
cld
1:
/* memcpy: return dest pointer */
movl B_ARG0,%eax
popl %esi
popl %edi
leave
ret
/* move words forwards */
0: cld
movl %edx,%ecx
sarl $2,%ecx
js 2f
rep
movsl
/* move bytes forwards */
movl %edx,%ecx
andl $3,%ecx
rep
movsb
2:
/* memcpy: return dest pointer */
movl B_ARG0,%eax
popl %esi
popl %edi
leave
ret
/* memcpy(to, from, count) */
ENTRY(memcpy)
ENTRY(memmove)
pushl %ebp
movl %esp,%ebp
pushl %edi
pushl %esi
movl B_ARG0,%edi
movl B_ARG1,%esi
jmp bcopy_common
|
